Declaring variables on same line fixes overflow

[Callum]

I have a program to calculate wattage from voltage and amps. If I declare V and I on different lines, then I get an overflow when V = 1000 and A = 100. If I declare them on the same line, then the overflow is fixed and doesn't occour

Private Sub cmdCalc_Click()

Dim W As Long
Dim Amps As Integer
Dim Voltage As Integer

Voltage = CInt(txtVolts.Text)
Amps = CInt(txtAmps.Text)

If Voltage >= 1 And Voltage <= 1000 Then
    If Amps >= 1 And Amps <= 100 Then
        W = CLng(Voltage * Amps)
        txtWatts.Text = W
    Else
        MsgBox "Enter amps between 1 and 100"
    End If
Else
    MsgBox "Enter volts between 1 and 1000"
End If

End Sub

[Rabbit]

Please use code tags when posting code.

Show us your declaration when it's on one line.

And is this VBA or VB? Because this is the VB forum and I suspect you're using VBA.

[Callum]

Dim Voltage, Amps As Integer

This is VB6.

[lexlythius]

Callum, this line

Dim Voltage, Amps as Integer

is equivalent to

Dim Voltage as Variant
DIm Amps as Integer

Not to this, as one might think

Dim Voltage as Integer
DIm Amps as Integer

[lexlythius]

Overflow does not occur because being Voltage a Variant, it becomes a Long which has an upper limit of (2^31)-1, whereas Integer upper limit equals (2^15)-1

[Rabbit]

Lexly is absolutely correct. On one line, the equivalent would be:

Dim Voltage as Integer, Amps as Integer

Which will result in an overflow. Just declare them as Longs.

[Callum]

Didn't realise the variable defaulted to variant when done one line. Thanks

[Killer42]

Variables always default to Variant type, unless you specify a type. The important point here is not that they were on a single line, but that you didn't specify a type for the first one.

You would get the same effect if you coded

Dim Voltage
Dim Amps As Integer