keyboard controlling arduino rc car with UDP packets (VB 2008)

**IronRazer** · Mar 20 '13, 09:50 PM

Hey kickpuncher,
I hope you don`t mind but, i rewrote some of your code and got it so it does not send the key again on release and so that when all keys are released it will send z once to stop the car. I think that`s what you where looking for.

Code:

Option Strict On
Imports System.Text
Imports System.Net
Imports System.Net.Sockets

Public Class Form1

    Dim GLOIP As IPAddress
    Dim GLOINTPORT As Integer
    Dim bytCommand As Byte() = New Byte() {}
    Dim udpClient As New UdpClient
    Dim cc As String = "z"
    Dim cclast As String = ""

    Public Declare Function GetAsyncKeyState Lib "user32" (ByVal vKey As Integer) As Integer
    Dim WithEvents Tmr As New Timer

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Tmr.Interval = 100
        Tmr.Start()
    End Sub

    Private Sub Tmr_Tick(ByVal sender As Object, ByVal e As System.EventArgs) Handles Tmr.Tick
        Tmr.Stop()

        If CBool(GetAsyncKeyState(Keys.Up) Or GetAsyncKeyState(Keys.Down)) Then

            Select Case True

                Case CBool(GetAsyncKeyState(Keys.Up))

                    If CBool((GetAsyncKeyState(Keys.Up)) And (GetAsyncKeyState(Keys.Left))) Then
                        Label1.Text = "Forwards Left"
                        cc = "b"

                    ElseIf CBool((GetAsyncKeyState(Keys.Up)) And (GetAsyncKeyState(Keys.Right))) Then
                        Label1.Text = "Forwards Right"
                        cc = "c"

                    Else
                        Label1.Text = "Forwards"
                        cc = "a"

                    End If

                Case CBool(GetAsyncKeyState(Keys.Down))

                    If CBool((GetAsyncKeyState(Keys.Down)) And (GetAsyncKeyState(Keys.Left))) Then
                        Label1.Text = "Backwards Left"
                        cc = "e"

                    ElseIf CBool((GetAsyncKeyState(Keys.Down)) And (GetAsyncKeyState(Keys.Right))) Then
                        Label1.Text = "Backwards Right"
                        cc = "f"

                    Else
                        Label1.Text = "Backwards"
                        cc = "d"

                    End If

            End Select

        ElseIf Not cc = "z" And Not CBool(GetAsyncKeyState(Keys.Down)) And Not CBool(GetAsyncKeyState(Keys.Up)) Then
            cc = "z"
            Label1.Text = "Stopped"
        End If

        If Not cclast = cc Then
            'UDP______________________________________________ _________

            Try
                GLOIP = IPAddress.Parse("192.168.1.177")
                GLOINTPORT = 8888
                udpClient.Connect(GLOIP, GLOINTPORT)
                bytCommand = Encoding.ASCII.GetBytes(cc)
                udpClient.Send(bytCommand, bytCommand.Length)

            Catch ex As Exception
                Console.WriteLine(ex.Message)

            End Try

            'UDP______________________________________________ _________
        End If

        cclast = cc

        Tmr.Start()

    End Sub

End Class

Also just a Tip you should use this line as the very first line of code in the program.

Code:

Option Strict On

It will catch all the errors of type conversion. By placing it in the code it will put a little blue line with a red spot on the end under each error. Then you can put your mouse over the red spot and it will pop up a little red box. You can then click on the red box and it will tell you how to fix the error. It is a very very handy option to use.

keyboard controlling arduino rc car with UDP packets (VB 2008)

keyboard controlling arduino rc car with UDP packets (VB 2008)

Comment